Milligrams of Morphine Equivalents Equations

Updated March 11, 2020

Caution: this is a work in progress. Don't take it too seriously (yet).

The intent of this analysis is to document different formulae used to calculate average daily MME, and examine conditions which may lead to bias.

For example, across 4 common formulae, for 2 simple prescriptions dispensed to the same patient on the same day for the same active ingredient, the following values of 30-day average daily MME were observed:

• 76 MME/day
• 94 MME/day
• 94 MME/day
• 53 MME/day

So, is this a "high dose" average daily MME by the arbitrary 90 MME/day standard?

The arithmetic details of how average daily MME is calculated can have a tremendous impact on interpretation. Yet, almost no publications include an explicit formula that would allow the results to be replicated.

# Assumptions¶

These are the common general assumptions made in calculating average daily MME for an individual using administrative data:

1. No missing data
2. All variables correctly specified (including days supply)
3. No other opioid prescriptions dispensed (e.g., cash pay in insurance claims data)
4. No external sources of opioids (e.g., leftover, diversion, illicitly manufactured)
5. All doses taken, and taken as described
6. Prescription was taken starting on the day dispensed
7. No counterfeits
8. Therapeutic equivalence of generics satisfied
9. No administration by routes other than oral
10. No differences between opioids in terms of subjective liking, clinical effectiveness, or side effects
11. No stability changes by storage or time

Additional assumptions for modeling in the exercise below:

1. Month has exactly 30 days
2. Only solid oral doseage forms prescribed
3. All prescriptions dispensed at midnight on date of dispensing

# Problem statement¶

Consider the following prescriber instructions:
This month, the patient should take one 30mg ER oxycodone twice-a-day for around-the-clock pain for 30 days, AND one 5mg oxycodone twice a day as needed for breakthrough pain. Both prescriptions are dispensed on the first day of the month.

**What is the 30-day average daily MME for this patient?**

Numerator: total MME for all prescriptions dispensed in 30-days

units x strength x conversion =
Rx1: 60qty x 30mg x 1.5 = 2700 MME per script
Rx2: 14qty x 5mg x 1.5 = 105 MME per script

|-|-|-|-|-|-|-|-|-|1|-|-|-|-|-|-|-|-|-|2|-|-|-|-|-|-|-|-|-|3| CALENDAR DAY
|-|-|-|-|-|-|-|-|-|0|-|-|-|-|-|-|-|-|-|0|-|-|-|-|-|-|-|-|-|0|
|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+|+| Rx1
|+|+|+|+|+|+|+|.|.|.|.|.|.|.|.|.|.|.|.|.|.|.|.|.|.|.|.|.|.|.| Rx2

${\sum_{i=0}^n M_i}$ = 30-Day Total MME: 2700 + 105 = 2805

What is the correct denominator?

1. Is it the sum of days supply?
literature example

$\cfrac {\sum_{i=0}^n M_i} {\sum_{i=0}^n d_i}$ = $\cfrac{2805 \text{ MME}} {37 \text{ days}} = 76\text{ average daily MME}$

2. Is it the total person-days since start of exposure (intent-to-treat)?
literature example

$\cfrac {\sum_{i=0}^n M_i} {max(\text{s+d}) - min(s) + 1}$ = $\cfrac{2805 \text{ MME}} {30 \text{ days}} = 94\text{ average daily MME}$

3. Is it the total person-days explicitly exposed, counting overlap days once?
literature example

Equation TBD = $\cfrac{2805 \text{ MME}} {30 \text{ days}} = 94\text{ average daily MME}$

Both #2 and #3 are 30d in this example but will not always be, e.g., 2 prescriptions separated by days.

4. Or, do you average the two?
literature example

$\cfrac{\sum{\cfrac{M_i} {d_i}}} {n}$ = $\cfrac{\cfrac{2700 \text{ MME}} {30 \text{ days}} + \cfrac{105 \text{ MME}} {7 \text{ days}}} {2} = 53\text{ average daily MME}$

The range of possible values for "average daily MME" (53 to 94) represnts 80% variation between the highest and lowest estimates, in this simple scenario, crossing the arbitrary 90 MME/day threshold for "high dose" opioids. When the prescriptions are not overlapping or are staggered, there can be a heightened chance of bias.

# In popular usage¶

## Nomenclature¶

We use the terms average daily MME interchangably with MME per day (summarized over a given time span).

## Origins and evolution¶

The concept of comapring the relative potency of opioid molecules to each other (or morphine) has its roots in clinical pharmacology, appearing in the biomedical literature around 1960, and codified in the essential textbook Goodman and Gilman's The Pharmacological Basis of Therapeutics. About 40 years ago, as new opioid molecules were becoming available for routine medical use, equianalgesic potency conversions were developed to assist clinical decision making when switching a patient from one opioid compound to another. In 1985, Foley formalized clinical practice for cancer pain management into an equianalgesic conversion table that serves as the archetype. Conversion tables started appearing in drug labels in the 1990s. The concept was attractive and one such table was notoriously embeded in a pen as a marketing leave-behind. By 2001, controversy was brewing on how to use the conversion factors among clinicians, with specific concern over the conversion factor for long-acting opioid methadone, which had emerged as a common chornic pain management option. Later, Fudin et al., Shaheen et al. and others detailed why the use of conversion factors is deeply questionable, not in the least because they do not take into account elimination half-life. To our knowledge, in 2006 the first documented use of morphine equivalents in an epidemiology study was published by Dasgupta et al., with a comprehensive conversion table assembled from various sources including drug labels. The original use showed API-level plots before the summarized version with MME, allowing for heterogeneity to be expressed alongside broader patterns across opioids.

During this time, several professional organizations and other groups created equianalgesic tables with varying conversion factors. Around 2010, Len Paulozzi at the Centers for Disease Control and Prevention (CDC) started circulating annaul spreadsheets with NDC and equianalgesic potency to researchers via email listservs. This particular set of conversion factors soon became the standard for research studies, but only offered guidance on measuring MME in a single prescription, and did not address overlapping scripts. In 2016, CDC issued guidelines for pain management that included strong cautions for opioid use above an arbitrary MME threshold, thereby suggesting a metric for intervention evaluation and surveillance, still with little regard to how to account for overlapping prescriptions. State laws and insurance policies with MME limits rapidly evolved, invoking the guidelines. Since 2015 there has been rapid increase in the number of publications using MME for epidemiologic studies, however, there is still no standard way for calculating MME in large healthcare datasets. In addition, there is little agreement on how to calculate MME for liquid medicines and non-oral routes of administration. Despite little agreement on the best use of MME, some have even called for MME to appear on drug packaging.

When used clinically, MME is an instantaneous mesaure used at the point of care, with an understanding of patient context. For example, when switching a patient to another opioid because of side effects, the remaining pills from the discontinued opioid will not be included in the calculation, however, in epidmeiology studies they will be. In this way, epidemiology approaches will overestimate prescribed exposure; and underestimate exposure from unsanctioned sources.

There is exposure ascertainment heterogeneity across the observational studies cited in the CDC Guidelines, creating opportunity for misclassification as we have previously stated. Yet, that these studies uniformly found increasing risk with exposure, regardless of formula used, demonstrates the fallibility of the existence of a hard threshold for overdose outcomes, as has been pointed out.

## Clinical care implications¶

Daily MME thresholds are used to modify care regimens for patients, without explicit formulae for how it is calcualted.

If the incoming claim was greater than the allowed daily MME, or if the incoming claim caused the total daily MME limit to be exceeded, the incoming claim was denied at point of sale...The MME reduction schedule was every 6 months: May 2017 to ≤250 MME/day; November 2017 to ≤200 MME/day, May 2018 to ≤150 MME/day. The next, and probably final, decrease for chronic non-cancer pain beneficiaries receiving an opioid will be November 14, 2018 and the total daily MME allowed limit will be ≤90 MME/day.
Arkansas Medicaid

## Public health implications¶

MME are routinely used in epidemiologic studies of opioid utilization today. The ease of calculation, based solely on arithmetic, coupled with the molecular underpinnings, create an ideal level of cognitive complexity to engender MMEs with an aura of authority. Collectively, MME offer the potential to agglomerate opioid compounds to create a summary metric for population level research and policy, similar to blood alcohol concentrations. However, this approach also obscures nuance between opioid compounds and formulations that may be worth of exploration.

The average daily MME per prescription was 48.1 in 2015, and prescriptions for 90 MME per day and up are considered to be "high-dose".
amFAR

Concerns with MME changes over time are exemplified by the following ICPE 2019 conference abstract, looking at Medicare and MarketScan insurance claims data on opioid prescribing after certain types of surgical procedures.

## Usage examples¶

This is not a comprehensive review of methods, but 4 major approaches that were explored in the hypothetical examples that follow this section.

### Equation 1 example¶

The total days’ supply per year is the sum of the days’ supply for all of the patient’s opioid prescriptions during the year, regardless of whether the dates of the prescriptions overlapped or continued... We included overlapping opioid prescriptions per day and calculated a daily MME by distributing the total MME for all opioid prescriptions over the days supplied.
Kimmel et al.

The duration of an opioid prescription was expressed as the number of days of supply, as obtained from the claim record. The strength of a prescription was expressed as the MME-per-day dose (computed as the product of drug strength per dose unit, number of units per day, and an MME conversion factor) to standardize potency across different opioid substances or dose forms (e.g., tablet or patch). We obtained information on drug strength per dose unit from the FDA, the National Center for Injury Prevention and Control, and the Red Book directories. The number of units per day was calculated by dividing the total number of units by the number of days of supply.
Zhu et al.

### Equation 2 example¶

For days with multiple prescriptions, MME was calculated for each prescription separately and summed to yield a single daily MME dosage. Each beneficiary was assigned an average daily MME dose by dividing the sum total daily MME for each beneficiary by the days in the “treatment period”: “Treatment period” was defined as the number of days between the first day of the beneficiary’s first opioid prescription and the last day of the beneficiary’s final opioid prescription in 2016 (the date of the final prescription plus the days supplied).
Centers for Medicare and Medicaid Services, page 11

Individual opioid prescriptions were organized into distinct 6-month periods. Within each time period, we used standard conversion tables to determine the morphine milligram equivalents (MME) per prescription and summed these to determine the total MME per period, then calculated an average daily opioid dose by dividing the total MME per period by 180 days.
Perez et al.

We calculated the average daily prescribed dose for each drug fill as the total MME dispensed divided by the number of person days of insurance enrollment in that period (that is, quarter)... Opioid prescriptions were allocated to a year and quarter, on the basis of the fill date and days supplied. For example, a 30 day prescription filled on 31 December 2008 would have been allocated as one day in quarter 4 of 2008 and 29 days in quarter 1 of 2009.
Moore et al.

We calculated the MME for a dispensation by multiplying the quantity of each prescription by the strength of the prescription (unit dispensed by milligrams of opioid). We then multiplied the resulting product by the conversion factor. We calculated the average daily MME dispensed for the relevant period (defined as 183 days for the baseline and 12-month periods and 90 days for the 6-month period) by adding the MMEs for the prescriptions dispensed during the period and dividing by the number of days in the period.
Campbell et al. PCORI

### Equation 3 example¶

Average daily MME was defined as the patient’s total MME from all prescriptions received during follow-up divided by the total available days supply from all prescriptions. If a beneficiary’s prescription was filled before the end of the previous prescription, the overlapping days were only counted once in the denominator.
Raman S et al.

### Equation 4 example¶

To calculate the average daily MME of a given opioid prescription, we multiplied the drug's strength by the quantity received and a medication‐specific MME conversion factor and divided by the days' supply received.17 The average daily MME for each prescription was then applied to all days for which the prescription was to be taken, according to the days' supply. If a beneficiary had more than 1 opioid prescription active on a given day, the MMEs for all prescriptions to be taken on that day were summed. We included MMEs from all sources of payment. Prescriptions for medication‐assisted treatment (MAT) for opioid use disorders were not included. For modeling purposes, we averaged each beneficiary's average daily MMEs across each calendar month. Naumann et al.

### Unclear¶

We also created patient-level variables to further describe opioid use, including total number of days receiving an opioid and mean daily MME.

Additional measures included MME per capita, average daily MME per prescription, and average days’ supply per prescription.
Guy et al. MMWR

The treatment period begins on an index prescription start date (IPSD) and ends on the last day of opioid supply during the measurement year. Total Daily MME is the total sum of the MME Daily Doses for all opioid dispensing events on one day. Average MME is the average MME for all opioids dispensed during the treatment period.
National Committee for Quality Assurance, pages 1 & 4

When >1 prescriptions overlapped by dates (e.g., separate prescriptions for long- and short-acting opioids, or for serial prescriptions filled early to avoid running out), we calculated the average daily MME through the duration of the overlapping prescriptions.
Hinami et al.

Average daily MME per prescription. For each opioid fill, the MME per day and then the average per month were calculated. Bohnert et al.

## Alternative approaches¶

Similar to Equation 3 but avoiding denominator hassle.

The volume and rate of opioid prescribing through the EMR were the key outputs measured. Data were analyzed as MME per patient encounter per month, MME per prescription, and number of opioid prescriptions per encounter.
Meisenberg BR et al.

# International Approaches¶

1. The World Health Organization uses defined daily dose as a metric for drug utilization. It is defined as:

Defined Daily Dose (DDD): The assumed average maintenance dose per day for a drug used for its main indication in adults.
WHO using data from Australia have shown that the established DDD for opioid analgesics may not have kept pace with modern pain management practice.

2. The Medication Posession Ratio (MPR) is widely used in medication adherence studies. There are 3 ways to calculate MPR, which take into account days supply and end dates to different degrees.

1. The Waiting Time Distribution and Inter-arrival Distance (slides) comes from Henrik Støvring, Anton Pottegård, and Jesper Hallas at Aarhus University in Denmark. The WTD methods arose out of neccesity; major Danish health datasets do not have indication, dosage, or refill information, making it impossible to observe when someone has stopped taking a drug (e.g., defining the end of the exposed period, or right administrative censoring). Thw WTD and IAD models take advatange of observed time between prescription refills to estimate how long people actually take to consume the medicines they are prescribed. It turns out that these distributions can be modeled with considerable (statistical) efficiency using parametric equations, meaning that patients are fairly consistent when they go get refills (including people at the extremes, which too is predictable) for other chronic conditions. Obviously opioids are complex, with acute and chronic pain both possible, so we are carefully exploring the feasability of using this measure in opioid studies.

# Programming¶

Stata/MP version 16.0

In [1]:
program drop _all
clear all

program define datainput
sort pt start rx
la var pt "Patient ID"
la var rx "Prescription number"
la var drug "Opioid active ingredient"
la var form "Extended/immediate-release or patch"
la var start "Date dispensed"
la var end "Last calendar day of month under observation"
*la var endimputed "Latest calendar date for any prescription including days supply"
la var units "Quantity dispensed"
la var strength "Dose strength in milligrams"
la var conv "Conversion factor relative to morphine"
la var days "Days supply indicated calculated by pharmacist"

gen endimputed=start+days-1
la var endimputed "Dispensing date + days supply"
order endimputed, a(end)

gen M=units*strength*conv
la var M "Total MME in given prescription"
list

end

// Performance metrics
program define metrics
qui: summ MME
di "-------------------"
di "Experiment results across 4 equations:"
di "Minimum average daily MME: " r(min)
di "Maximum average daily MME: " r(max)
di "range: "r(max)-r(min)
di round(r(max)/r(min),.1) "-fold difference between highest and lowest"
end

frame create composite equation MME experiment
frame post composite (0) (.) (0)

// Composite programs
program define runexperiment
version 16
qui: datainput
qui: frame create results equation MME
qui: eq1
qui: eq2
qui: eq3
qui: eq4
qui: order totptime, a(eq4)
di "-------------------"
di "Total therapy-days accounting for any overlap: " totptime[1] " days out of 30"
*list
*di "Resize the browser window if line wraps in table."
qui: frame change results
metrics
list
frame change default
qui: frame drop results
end

// Compile composite results
program define compileresults
version 16
frame change composite
frame copy composite long
gen j=_n
qui: reshape wide MME, i(j) j(experiment)
qui: collapse (max) MME*, by(equation)
qui: save compositeresult, replace
list
end

program ranktable
frame change long
qui: bysort experiment: egen rank=rank(MME)
qui: replace rank=rank^1
qui: egen max=max(experiment)
qui: bysort equation: egen seq=rank(-MME), unique
set scheme economist
scatter equation experiment [w=rank], xlabel(none)
end


To be completed later.

The base Excel file can be found here. The column naming conventions follow from the simulation data above.

• column C = prescription number rx
• column D = API drug

# Equations¶

Equations should be considered with caution -- they have not been vetted and checked over by others. Revision suggestions are welcome!

Where:
$M_i$ .......... MME for given prescription i
$q$ .......... Quantity (untis) dispensed
$d$ .......... Days supply
$s$ .......... Start date of prescription (day of dispensing)
$e$ .......... End date of prescription (dispensing date plus days supply)
$n$ .......... Total number of prescriptions

## Equation 1¶

Average daily MME is calculated by dividing (the sum of MMEs across all prescriptions) by (the sum of days supply) over the entire observation period.

Average daily MME = $\cfrac {\sum_{i=0}^n M_i} {\sum_{i=0}^n d_i}$

Spreadsheet formula: =ROUND(((L7+L8)/(K7+K8)),1)

In [2]:
// Equation 1

program define eq1
* Numerator: sum MME for each prescription across time period
bysort pt: egen num = total(M)

* Denominator: sum days supply for each prescription across whole time period
bysort pt: egen den = total(days)

* Divide
bysort pt: gen eq1=round(num/den)
la var eq1 "MME Equation 1"
drop num den
frame post results (1) (eq1)
frame post composite (1) (eq1) (exp)
end


## Equation 2¶

Average daily MME is calculated by dividing (the sum of MMEs across all prescriptions) by (the number of calendar days between the start of the first prescription and the end of the last prescription).

Average daily MME = $\cfrac {\sum_{i=0}^n \text{M}} {max(\text{s+d}) - min(s) + 1}$

Spreadsheet formula: insert formula here

In [3]:
// Equation 2

program define eq2
* Numerator: sum MME for each prescription across time period
bysort pt: egen num = total(M)

* Denominator: maximum calendar days difference between earliest and last prescription
bysort pt: egen min=min(start)
bysort pt: egen max=max(end)
gen den = max-min+1

* Divide
bysort pt: gen eq2=round(num/den)
la var eq1 "MME Equation 2"
drop num den min max
frame post results (2) (eq2)
frame post composite (2) (eq2) (exp)
end


## Equation 3¶

Average daily MME is calculated by dividing (the sum of MMEs across all prescriptions) by (the total person-days explicitly exposed, counting overlap days once). There are other ways to implement this equation in code, but the approach below uses the brace counting algorithm.

Average daily MME = Equation TBD

Spreadsheet formula: can anyone help with this?

In [4]:
// Equation 3

program define eq3
* Duplicate copies to create separate lines for start and end dates
expand 2, gen(ender)

// Generate bracedates
gen bracedate=start if ender==0
replace bracedate=endimputed if ender==1

// Count number of rows per person
sort pt bracedate ender
by pt: gen counter=_n

// Calculate difference between adjacent bracedates
sort pt bracedate counter
gen diff = bracedate-bracedate[_n-1] if counter!=1

// fix difference between adjacent days and same days
replace diff=bracedate-bracedate[_n-1] if bracedate==bracedate[_n-1]+1
replace diff=0 if bracedate==bracedate[_n-1]

// Check for errors: no observations
//    tab diff if counter==1 & diff!=.

// Create running counter
gen ender2=ender
replace ender2=-1 if ender==1
replace ender2=1 if ender==0
by pt: gen running=sum(ender2)
drop ender2

// Generate person-days exposed
bysort pt bracedate counter: egen ptime=total(diff) if (running!=1 | running[_n-1]>1)
replace ptime=1 if diff==1 & running==1
replace ptime=1 if running==1 & ptime==.
replace ptime=1 if counter==1
sort pt bracedate counter
by pt: egen totptime=total(ptime)

// Average daily MME
keep if ender==0

* Numerator: total MME
bysort pt: egen num=total(M)

* Denominator: use totptime

* Divide
gen eq3 = round(num/totptime)
la var eq3 "MME Equation 3 - brace counting"
drop num ender bracedate diff counter running ptime
order eq3, a(eq2)
frame post results (3) (eq3)
frame post composite (3) (eq3) (exp)
end


## Equation 4¶

Average daily MME is calculated by taking the mean of the average across all prescriptions of the daily MME (MME $\div$ days supply) per script.

Average daily MME = $\cfrac{\sum{\cfrac{M_i} {d_i}}} {n}$

Excel formula: insert formula here

In [5]:
// Equation 4

program define eq4
gen temp=M/days
bysort pt: egen temp2=mean(temp)
gen eq4=round(temp2)
la var eq4 "MME Equation 4"
note eq4: Average of individual prescription daily MME, by person
drop temp
frame post results (4) (eq4)
frame post composite (4) (eq4) (exp)
end


# Experiments¶

## Experiment 1: Base scenario ER+IR¶

Using the core example described above, 2 prescriptions :

• One 20mg ER oxycodone twice-a-day for 30 days
• One 5mg IR oxycodone as needed for breakthrough pain, written as 7 day supply
• Both prescriptions are dispensed on the first day of the month
In [6]:
clear
qui: input exp pt rx str3 drug str2 form start end units strength conv days
1 100 1 "oxy" "ER" 1 30 60 30 1.5 30
1 100 2 "oxy" "IR" 1 30 14 5 1.5 7
end

runexperiment



. runexperiment
-------------------
Total therapy-days accounting for any overlap: 30 days out of 30
-------------------
Experiment results across 4 equations:
Minimum average daily MME: 53
Maximum average daily MME: 94
range: 41
1.8-fold difference between highest and lowest

+----------------+
| equation   MME |
|----------------|
1. |        1    76 |
2. |        2    94 |
3. |        3    94 |
4. |        4    53 |
+----------------+


## Experiment 2: One ER, 2 IR¶

3 prescriptions :

• One 20mg ER oxycodone twice-a-day for 30 days, filled on Day 1
• One 5mg IR oxycodone as needed for breakthrough pain, written as 7 day supply, filled on Day 1
• One 5mg IR oxycodone as needed for breakthrough pain, written as 7 day supply, filled on Day 1
In [7]:
clear
qui: input exp pt rx str3 drug str2 form start end units strength conv days
2 100 1 "oxy" "ER" 1 30 60 20 1.5 30
2 100 2 "oxy" "IR" 1 30 14 5 1.5 7
2 100 3 "oxy" "IR" 10 30 14 5 1.5 7
end

runexperiment



. runexperiment
-------------------
Total therapy-days accounting for any overlap: 30 days out of 30
-------------------
Experiment results across 4 equations:
Minimum average daily MME: 30
Maximum average daily MME: 67
range: 37
2.2-fold difference between highest and lowest

+----------------+
| equation   MME |
|----------------|
1. |        1    46 |
2. |        2    67 |
3. |        3    67 |
4. |        4    30 |
+----------------+


## Experiment 3: Two IR¶

2 IR prescriptions:

• One 5mg IR oxycodone prn, written as 7 day supply, filled on Day 1
• One 5mg IR oxycodone prn, written as 7 day supply, filled on Day 10
In [8]:
clear
qui: input exp pt rx str3 drug str2 form start end units strength conv days
3 100 1 "oxy" "IR" 1 30 14 5 1.5 7
3 100 2 "oxy" "IR" 10 30 14 5 1.5 7
end

runexperiment



. runexperiment
-------------------
Total therapy-days accounting for any overlap: 14 days out of 30
-------------------
Experiment results across 4 equations:
Minimum average daily MME: 7
Maximum average daily MME: 15
range: 8
2.1-fold difference between highest and lowest

+----------------+
| equation   MME |
|----------------|
1. |        1    15 |
2. |        2     7 |
3. |        3    15 |
4. |        4    15 |
+----------------+


## Experiment 4: Two overlapping IR oxycodone¶

2 IR prescriptions, more prn use than expected scenario:

• One 5mg IR oxycodone prn 2 pills/day, written as 7 day supply, filled on Day 1
• One 5mg IR oxycodone prn, written as 7 day supply, filled on Day 3
In [9]:
clear
qui: input exp pt rx str3 drug str2 form start end units strength conv days
4 100 1 "oxy" "IR" 1 30 14 5 1.5 7
4 100 2 "oxy" "IR" 3 30 14 5 1.5 7
end

runexperiment



. runexperiment
-------------------
Total therapy-days accounting for any overlap: 9 days out of 30
-------------------
Experiment results across 4 equations:
Minimum average daily MME: 7
Maximum average daily MME: 23
range: 16
3.3-fold difference between highest and lowest

+----------------+
| equation   MME |
|----------------|
1. |        1    15 |
2. |        2     7 |
3. |        3    23 |
4. |        4    15 |
+----------------+


## Experiment 5: One hydrocone IR + 1 oxycodone IR¶

2 IR prescriptions, switching from oxycodone to hydrocodone because of side effects but assuming both scripts were consumed:

• One 5mg IR oxycodone prn 2 pills/day, written as 7 day supply, filled on Day 1
• One 5mg IR hydrocodone prn, written as 7 day supply, filled on Day 3
In [10]:
clear
qui: input exp pt rx str3 drug str2 form start end units strength conv days
5 100 1 "oxy" "IR" 1 30 14 5 1.5 7
5 100 2 "hyd" "IR" 3 30 14 5 1 7
end

runexperiment



. runexperiment
-------------------
Total therapy-days accounting for any overlap: 9 days out of 30
-------------------
Experiment results across 4 equations:
Minimum average daily MME: 6
Maximum average daily MME: 19
range: 13
3.2-fold difference between highest and lowest

+----------------+
| equation   MME |
|----------------|
1. |        1    13 |
2. |        2     6 |
3. |        3    19 |
4. |        4    13 |
+----------------+


## Experiment 6: leftover pills destroyed¶

Now, let's run the previous experiment again, but assume that the remaining 10 tablets of oxycodone after the first 2 days was disposed of.

In [11]:
clear
qui: input exp pt rx str3 drug str2 form start end units strength conv days
6 100 1 "oxy" "IR" 1 30 14 5 1.5 7
6 100 2 "hyd" "IR" 3 30 14 5 1 7
end

// Assume first prescritption was discontinued and disposed of before starting the second
replace days=2 if rx==1
replace units=4 if rx==1
runexperiment



. replace days=2 if rx==1

. replace units=4 if rx==1

. runexperiment
-------------------
Total therapy-days accounting for any overlap: 9 days out of 30
-------------------
Experiment results across 4 equations:
Minimum average daily MME: 3
Maximum average daily MME: 13
range: 10
4.3-fold difference between highest and lowest

+----------------+
| equation   MME |
|----------------|
1. |        1    11 |
2. |        2     3 |
3. |        3    11 |
4. |        4    13 |
+----------------+


# Summary of Findings¶

In [12]:
compileresults
ranktable


+-----------------------------------------------------------+
| equation   MME0   MME1   MME2   MME3   MME4   MME5   MME6 |
|-----------------------------------------------------------|
1. |        0      .      .      .      .      .      .      . |
2. |        1      .     76     46     15     15     13     11 |
3. |        2      .     94     67      7      7      6      3 |
4. |        3      .     94     67     15     23     19     11 |
5. |        4      .     53     30     15     15     13     13 |
+-----------------------------------------------------------+

(analytic weights assumed)
(analytic weights assumed)
(analytic weights assumed)


# Formula from CDC Guideline-cited studies¶

Ranapurwala et al. reviewed the 36 studies cited in the CDC Guidelines. The verbatim text from Methods sections of the studies using MME per day are reproduced below. Some studies used maximum MME. Some used a calendar based time period. Some summed the days supply. However, despite stating in words what was apparent to the investigators, only a handful provided enough detail to reproduce the exact calculation of average daily MME.

## NO MME calculations (n=10)¶

Allan 2005, Banta-Green 2009, Cicero 2012, Gaither 2016, Hwang 2016, Jones 2015, Mitra 2013, Reid 2002, Wild 2010

Park 2005: Daily benzodiazepine dose mg/day calculated by unspecified formula

## Studies that used some form of MME calculation over time (n=26)¶

Bhonert 2011: Next, each patient’s total maximum daily dose for each day of the study observation period was calculated by add- ing the daily doses of all fills that covered that particular day. The specific daily dose contributed by each fill was determined by dividing the total morphine-equivalent milligrams dispensed in that fill by the number of days supplied. This measurement of dose reflects the maximum daily dose prescribed and not necessarily the actual amount consumed. Morphine- equivalent maximum daily dose was converted into a categorical variable with the values of 0 mg, 1 mg to less than 20 mg, 20 mg to less than 50 mg, 50 mg to less than 100 mg, and 100 mg or more. In addition, a time-varying indicator of whether patients were pre- scribed a regularly scheduled opioid plus a simultaneous as-needed opioid was coded for each day of the study observation period that a patient had at least 1 opioid prescription using the fol- lowing 3 mutually exclusive categories: 0, only regularly scheduled opioids; 1, only as-needed opioids; or 2, both a regularly scheduled opioid and as-needed opioid prescriptions.

Bohnert 2009: Each patient’s prescribed opioid dosage on their index date was calculated by adding the daily doses of all fills that covered that particular day.

Boscarino 2016: counting the number of prescription orders in the EHRs in the past 12 months before OD (0, 1–2, 3–8, 9+ orders. We note that calculation of a “morphine equivalent dose” is limited with nonplan members, because these types of patients may receive opioids from multiple sources and prescription claims data are unavailable.

Cochran 2016:MME was constructed by converting total within-episode opioid supply into morphine equivalents, dividing by days supplied, and coding into 4 levels (Z 100 MME/d, 50– < 100 MME/d, 20– < 50 MME/d, <20 MME/d). Level of MME/day varied by individual across episodes.

Cowan 2005: Not specified

Dasgupta 2015: The average daily MME per individual in 2010 was calculated by taking the total milligrams and dividing by the days supply, taking into account overlapping prescriptions.

Dilokthornsakul 2016: Not specified

Dunn 2010: We then calculated the average daily morphine equivalent dose dispensed for 90-day exposure windows by adding the morphine equivalents for the prescriptions dispensed during the 90 days and then dividing by 90. For each 90-day exposure window and each person, we calculated the average daily opioid dose dispensed and divided these into 5 categories: none, 1 to 19 mg, 20 to 49 mg, 50 to 99 mg, and 100 mg or more. We included opioid dose as a time-varying covariate, estimated for continuously updated 90-day exposure windows. Participants could be classified as either exposed to opioids (at any of 4 dosage levels) or unexposed on any given day, on the basis of their average daily opioid dose during the previous 90 days, including the event date.

Edlund 2014: Average daily dose was measured in morphine equivalents and grouped as none (0 mg), low dose (1–36 mg), medium dose (36–120 mg), and high dose (120+mg).

Gomes 2011: The dose of opioid was calculated as the number of tablets dispensed multiplied by the strength of the pills (in milligrams) for each prescription. The average daily dose for each of these prescriptions was then calculated as the dose (in milligrams) divided by the number of days’ supply for which the prescription was written, converted to morphine equivalents using morphine equivalence ratios used by the Canadian National Opioid Use Guideline Group.

Gomes 2011 Open Med: For each individual who received at least one opioid prescription in a given calendar year, we calculated the mean daily dose dispensed (mg) of oral morphine, or equivalent, on the basis of the person’s first 90 days of opioid therapy. If the supply of drug dispensed for a prescription in that interval extended beyond 90 days, we excluded the excess. The adjusted total amount of morphine equivalents dispensed over the 90 days was divided by 90 to obtain the mean daily dose for the period.

Baumblatt 2014: To calculate the mean daily dosage, all opioid prescriptions were combined and converted to MMEs and divided by 365 days. We categorized mean daily dosage into less than20,20to40,41to80,81to100,101to200,201to400, and more than 400 MMEs/d and defined high risk as a mean of more than 100 MMEs/d for a year.

Ilgen 2016: Maximum morphine-equivalent daily opioid dose was modeled as time-varying and recoded into the following categories: 0 mg, 1 to ,20 mg/d, 20 to ,50 mg/d, 50 to ,100 mg/d, and 1001 mg/d.2,10 These dosage categories were chosen to allow for comparison with other published work on unintentional overdose2 as well recent recommendations that caution against prescribing more than 90 to 100 mg/d.25 To avoid double-counting dosage, opioid fills that seemed to be contin- uations of the same treatment plan (ie, were the same opioid formulation and dosage) were assumed to not start until the end of the days’ supply of the previous fill. Also consistent with the Bohnert article,25 for each day that an individual had at least 1 opioid prescription, a 3-level time-varying indicator of opioid fill type was calculated to reflect schedule, with the categories of: only regularly scheduled opioids; only pro re nata (PRN) opioids; or both regularly scheduled opioid and PRN opioid prescriptions.

LaRochelle 2016: We calculated the morphine-equivalent dos- age (MED) for each opioid dispensing using estab- lished conversion tables (14). We calculated a daily MED by distributing the total MED for each dispensing over the days supplied and summing the total of over- lapping dispensings on each day. Good figure illustrating approach to MME calculationg with overlapping scripts.

Liang 2005: We calculated the mean daily MED for filled opioid prescriptions for each 6-month interval by dividing the total MED by total days'; supply covered by all these prescriptions. The total MED was computed from all opioids dispensed in a 6-month interval multiplied by strength (in milligrams) and then multiplied by a morphine equivalent conversion factor derived from published data,10,23 conversion tables on the Internet, and drug information resources

Liang 2006: As reported previously, total morphine equivalent dose was calculated from all filled opioid prescriptions over 6 months as well as average daily dose over this time- frame [14,15]. As in other studies, average daily opioid dose was examined in four categories: <20, 20–49, 50– 99, and >100 mg [12,14–17]; and total opioid dose was examined in four categories: >190, 191–450, 451– 1830, and >1830 mg [14] [16]. We created a three-level opioid dose factor (High if daily dose > 100 mg; Medium if daily dose 50–99 mg and total dose > 1830 mg; Low for all others).

Miller 2005: To assess and control for the effect of the opioid dose, we con- verted each opioid agent to the morphine-equivalent dose fol- lowing the method of Von Korff et al.17 We computed the mor- phine-equivalent mean daily dose by dividing the total quantity prescribed by days’ supply and converted the daily dose thus calculated into a corresponding morphine-equivalent dose. After the conversion, prescriptions in morphine-equivalent mean daily doses were categorized as 1 mg to less than 20 mg, 20 mg to less than 50 mg, 50 mg to less than 100 mg, and 100 mg or greater.

Naliboff 2011: Opioid medication dosages were taken from the com- puterized pharmacy record and were converted into morphine equivalents per day in order to have a stan- dardized unit for reporting opioid amounts across differ- ent drugs.

Paulozzi 2012: we calculated the dosage of opioid prescribed in MME per day [27] in three different ways. The single peak dosage was the highest amount per day in any single opioid prescription. The total peak dosage was the highest dosage per day at any time during the exposure period after summing dosages from all overlapping opioid prescriptions. The average dosage was the average daily opioid dosage during the entire study period from all opioid prescriptions combined. For regression analysis, we categorized each measure of daily dosage into 0–40, >40–120, and >120 MME/day.

Paulozzi 2014: Indicators of general opioid use included the mean and median days of use (where one or more opioid prescriptions was active) and mean and median daily dosages for opioids in morphine milligram equivalents (MMEs).

Ralphs 1994: not specified

Ray 2016: The analysis included a time-dependent analysis of the relation of duration of study drug therapy and dose during follow-up to total study mortality. Duration was defined as cu- mulative dispensed days of therapy on the day a study drug prescription was filled. Cut points for low (≤cut point) vs high dose (>cut point) were the approximate median time- dependent doses: 60-mg/d morphine equivalents, 600- mg/d gabapentin equivalents, and 40-mg/d amitriptyline equivalents.

Sullivan 2010: Opioid dose per day supplied was calculated by adding the total morphine equivalents for the three major opioid groups and dividing by the sum of the total days supply (assuming maximum authorized use as calculated by the dispensing pharmacist). If the total days supply exceeded the number of days in the period (180 days), suggesting concurrent use of different opioid types, the daily dose was calculated by dividing the total dose dispensed by 180 days.

Tennant 1982: not specified

Turner 2015: The total MED was computed by summing the MEDs for all opioid prescriptions within a given 6-month interval. The mean daily MED in a 6-month interval was calculated by dividing the total MED by days’ supply for all prescrip- tions in that interval, excluding overlapping days. We ex- amined five categories for the mean daily MED (i.e., 0, 1– 19, 20–49, 50–99, and ≥100 mg), similar to other stud- ies.9,10 For the first overdose, the mean daily MED was based on data from exactly 6 months before that event

Zedler 2014: For each opioid prescription dispensed during the baseline period, the product of the number of units dispensed and the opioid strength per unit (milligrams) was divided by the number of days supplied. The resulting opioid daily dose dispensed (milligrams per day) was then multiplied by a conversion factor derived from published sources to estimate the daily dose in morphine equivalents (MED) (see Table 2) [37–42]. The maximum prescribed daily MED during the baseline period was calculated for each patient by summing the daily MED for all opioid prescriptions dispensed to the patient during those 6 months. It reflects the maximum prescribed daily dose and not necessarily the actual amount consumed.

fin.